opentelemetry-java-instrumentation/instrumentation/play-ws/play-ws-1.0/play-ws-1.0.gradle

// Set properties before any plugins get loaded
ext {
  minJavaVersionForTests = JavaVersion.VERSION_1_8
}

apply from: "$rootDir/gradle/instrumentation.gradle"
apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  latestDepTest {
    dirName = 'test'
  }
}

muzzle {
  pass {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.11'
    versions = '[1.0.0,2.0.0)'
    assertInverse = true
  }
  pass {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.12'
    versions = '[1.0.0,2.0.0)'
    assertInverse = true
  }
  fail {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.13'
    versions = '[,]'
  }
}

def scalaVersion = '2.12'

dependencies {
  compileOnly group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '1.0.2'

  implementation project(':instrumentation:play-ws:play-ws-common')
  testImplementation project(path: ':instrumentation:play-ws:play-ws-common', configuration: 'testArtifacts')

  // These are to ensure cross compatibility
  testImplementation project(':instrumentation:netty:netty-4.0')
  testImplementation project(':instrumentation:netty:netty-4.1')
  testImplementation project(':instrumentation:akka-http-10.0')

  testImplementation group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '1.0.2'

  latestDepTestImplementation group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '1.+'
}