// Set properties before any plugins get loaded
ext {
  minJavaVersionForTests = JavaVersion.VERSION_1_8
}

apply from: "${rootDir}/gradle/instrumentation.gradle"
apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  latestDepTest {
    dirName = 'test'
  }
}

muzzle {

  pass {
    module = 'play-ahc-ws-standalone_2.11'
    group = 'com.typesafe.play'
    versions = '[2.0.0,]'
    assertInverse = true
  }

  pass {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.12'
    versions = '[2.0.0,2.1.0)'
    skipVersions += '2.0.5' // Bad release
    assertInverse = true
  }

  // No Scala 2.13 versions below 2.0.6 exist
  pass {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.13'
    versions = '[2.0.6,2.1.0)'
  }
}

def scalaVersion = '2.12'

dependencies {
  compileOnly group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '2.0.0'

  compile project(':instrumentation:play-ws:play-ws-common')
  testCompile project(path: ':instrumentation:play-ws:play-ws-common', configuration: 'testArtifacts')

  // These are to ensure cross compatibility
  testCompile project(':instrumentation:netty:netty-4.0')
  testCompile project(':instrumentation:netty:netty-4.1')
  testCompile project(':instrumentation:akka-http-10.0')

  testCompile group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '2.0.0'

  latestDepTestCompile group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '2.0.+'
}