// Set properties before any plugins get loaded
ext {
  minJavaVersionForTests = JavaVersion.VERSION_1_8
}

apply from: "${rootDir}/gradle/java.gradle"

apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  latestDepTest {
    dirName = 'test'
  }
}

muzzle {
  pass {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.11'
    versions = '[1.0.0,2.0.0)'
    assertInverse = true
  }
  pass {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.12'
    versions = '[1.0.0,2.0.0)'
    assertInverse = true
  }
  fail {
    group = 'com.typesafe.play'
    module = 'play-ahc-ws-standalone_2.13'
    versions = '[,]'
  }
}

def scalaVersion = '2.12'

dependencies {
  compileOnly group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '1.0.2'

  testCompile project(':dd-java-agent:instrumentation:java-concurrent')

  // These are to ensure cross compatibility
  testCompile project(':dd-java-agent:instrumentation:netty-4.0')
  testCompile project(':dd-java-agent:instrumentation:netty-4.1')
  testCompile project(':dd-java-agent:instrumentation:akka-http-10.0')

  testCompile group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '1.0.2'

  latestDepTestCompile group: 'com.typesafe.play', name: "play-ahc-ws-standalone_$scalaVersion", version: '1.+'
}